# You can place the script of your game in this file.

init:
    image logo = "logo.png"
    
    # DAVID SPRITES
    image side david = "sprites/david/normal.png"
    image side david normal = "sprites/david/normal.png"
    image side david angry_closed = "sprites/david/angry_closed.png"
    image side david angry_open = "sprites/david/angry_open.png"
    image side david annoyed_open = "sprites/david/annoyed_open.png"
    image side david annoyed = "sprites/david/annoyed.png"
    image side david normal_open = "sprites/david/normal_open.png"
    image side david skeptical_open = "sprites/david/skeptical_open.png"
    image side david skeptical = "sprites/david/skeptical.png"
    image side david smile = "sprites/david/smile.png"
    image side david surprised_closed = "sprites/david/surprised_closed.png"
    image side david surprised = "sprites/david/surprised.png"
    image side david teasing = "sprites/david/teasing.png"
    
    image david = "sprites/david/normal.png"
    image david normal = "sprites/david/normal.png"
    image david angry_closed = "sprites/david/angry_closed.png"
    image david angry_open = "sprites/david/angry_open.png"
    image david annoyed_open = "sprites/david/annoyed_open.png"
    image david annoyed = "sprites/david/annoyed.png"
    image david normal_open = "sprites/david/normal_open.png"
    image david skeptical_open = "sprites/david/skeptical_open.png"
    image david skeptical = "sprites/david/skeptical.png"
    image david smile = "sprites/david/smile.png"
    image david surprised_closed = "sprites/david/surprised_closed.png"
    image david surprised = "sprites/david/surprised.png"
    image david teasing = "sprites/david/teasing.png"
    
    # ELENA SPRITES
    image elena = "sprites/elena/normal.png"
    image elena normal = "sprites/elena/normal.png"
    image elena concerned_closed = "sprites/elena/concerned_closed.png"
    image elena concerned_open = "sprites/elena/concerned_open.png"
    image elena defiant_open = "sprites/elena/defiant_open.png"
    image elena defiant = "sprites/elena/defiant.png"
    image elena hmph_open = "sprites/elena/hmph_open.png"
    image elena hmph = "sprites/elena/hmph.png"
    image elena normal_open_up = "sprites/elena/normal_open_up.png"
    image elena normal_open = "sprites/elena/normal_open.png"
    image elena normal_up = "sprites/elena/normal_up.png"
    image elena side = "sprites/elena/side.png"
    image elena skeptical_closed = "sprites/elena/skeptical_closed.png"
    image elena skeptical_open = "sprites/elena/skeptical_open.png"
    image elena smile = "sprites/elena/smile.png"
    image elena surprised_closed = "sprites/elena/surprised_closed.png"
    image elena surprised = "sprites/elena/surprised.png"
    image elena regret = "sprites/elena/regret.png"
    image elena blush = "sprites/elena/blush.png"
    
    # BGs
    image elevator = "bg/Elevator.png"
    image elevator 1 = "bg/Elevator-1-only.png"
    image elevator 78 = "bg/Elevator-78-only.png" 
    image elevator doors = "bg/Elevator-doors.png"
    image elevator blank = "bg/Elevator-blank.png"
    image office day = "bg/Office-Day.png"
    image office evening = "bg/Office-Evening.png"
    image office night = "bg/Office-Night.png"
    image office night light = "bg/Office-Light-on.png"
    image rain = "bg/Rain.png"
    image ed1 = "bg/elevator-door-top.png"
    image ed2 = "bg/elevator-door-bottom.png"
    image elevator wall = "bg/elevatorwall.png"
    
    # MUSIC / SOUNDS
    $ casual = "sounds/casual.ogg"
    $ distrust = "sounds/distrust.ogg"
    $ untold = "sounds/untold.ogg"
    $ mystery = "sounds/mystery.ogg"
    $ rainy = "sounds/rain.ogg"
    $ elevatording = "sounds/corsica-s__ding.ogg"
    
    $ sdissolve = Dissolve(0.25) # a faster dissolve
    $ dissolve2 = Dissolve(3) # a faster dissolve
    
    $ elena_pts = 0
    
# Declare images below this line, using the image statement.
# eg. image eileen happy = "eileen_happy.png"

# Declare characters used by this game.
define d = Character('DAVID', image="david", color="#8e5244", who_xoffset=270, what_xoffset=220, what_xmaximum=785)
define e = Character('Elena', color="#6b8e44")
define e1 = Character('Elevator Girl', color="#6b8e44")
define j = Character('Jonathan', color="#8F7F45")
define rain_nvl = Character(None, kind=nvl, window_background="bg/Rain.png", window_ypos=-40, window_xpos=-40, what_xoffset=40, what_yoffset=80, what_color="#6C8DAB", what_outlines=[(1, "#293C4D", 0, 0)])

transform files_pan:
    xalign 0.0 xanchor 0.0
    linear 25.0 xalign 1.0
transform files_pan2:
    linear 25.0 xalign 0.0

label qanda:
    play music untold fadeout 1
    rain_nvl "{w=0.7}Hello! Camille speaking. First off, congrats on unlocking the True Ending! I hope you enjoyed The Elevator… Then again, I suppose you wouldn’t be reading this if you didn’t care. Anyway, I’m just going to discuss a few things about the story and characters. I originally came up with the idea for the VN as a school project… After presenting it, I ended up fleshing things out a bit more. The project had a word count limit, you see, and I wanted actual players to get the full experience." with dissolve
    extend "\n\nThe Elevator takes place in the future… If you Google the \"Green River Killer\" that David mentions, you’ll see that he was an actual person who killed so many people in the 1980’s and 90’s that he’s considered to be America’s single most prolific serial killer to date. Since David says that the Green River Killer was active \"centuries ago\", this puts the date of The Elevator somewhere in the mid-2000’s… I’d say somewhere between 2400 and 2600. (as a bit of a side note, Pierre and co. from Ristorante Amore were born in the 2430’s)"
    nvl clear
    rain_nvl "This future is not so far out that our society is run by robots and everyone teleports everywhere, but at this point in time, there is no more central government. Countries, states, and cities have been fragmented and each district has its own local government. The police, healthcare, and other social services are no longer national government-funded, so the power of, say, the police force depends highly upon how wealthy that particular district is. Many services are now privately-run enterprises instead of guaranteed for all citizens. Without any welfare programs to speak of, people who don't have enough money to feed themselves or pay taxes end up in debtors' prison or dead. Poorer districts often seem like chaotic anarchies and in some places, private detectives and volunteer militias have more power than the police. With local governments having to do so much, it's easy for illegal immigrants, criminals, and the like to slip through the cracks. The bureaucracy hasn't changed much despite being on a local level, so many people choose to subvert the system entirely."
    nvl clear
    rain_nvl "This is the world David lives in. Disillusioned by his time in the district police force, he decided to leave with his friend Jonathan and start a business that they really believed in."
    extend "\n\nI was trying to mislead people with the premise of the game a little… I wonder if anybody thought this would be some sort of dating sim where David and Elena hook up. (laughs) Sorry about that. The Elevator is a bit of a cautionary tale… Though what it’s cautioning you about depends on how you want to interpret things and which character you identify with more, I suppose. This is probably one of the least interactive VNs we’ll ever make here at Cyanide Tea, but I hope that it was still enjoyable."
    extend "\n\nAbout the characters… There are really only four of them and one of them is only around in David’s memories, but let me talk about them briefly."
    nvl clear
    rain_nvl "Let’s start with David Carmichael, the main character. I originally intended to have him be more like a grumpy older man, but he ended up being more introverted and introspective than I expected. He’s a man who can’t move on from his past because he isn’t sure if he did the right thing—then he feels stupid for starting to sympathize with a serial killer and the cycle of self-doubt and self-rejection starts all over again. He rejects Elena’s small attempts at companionship because he doesn’t think it’s possible for them to be anything more than acquaintances—Elena’s not very happy about this, of course."
    extend "\n\nI hope not too many people are able to relate to David… Like him, I had a very dark period in my life where I questioned everything I did and didn’t feel like I was worth anything. It didn’t last nearly as long for me as it did for David, but it’s a very awful world to live in no matter how long you’re there. Still, I like David a lot. Even when he’s feeling down and unsure, he keeps going. He cares more about helping people than about boosting his own ego… I mean, if even Avery McMillan was able to take a shine to him, David must be a pretty swell guy. For the record, David is 43 years old."
    nvl clear
    rain_nvl "Jonathan North is the upbeat best friend/partner in justice. He’s been best friends with David for years and they’re about the same age, though I’d say that Jonathan is definitely a bit younger. He’s seen some pretty nasty things in his life, but he’s able to cope with his line of work better than David does—probably because Jon doesn’t have a big, dark memory to cling to."
    extend "\n\nI think of him as the Chris Rock to David’s Jackie Chan… If Jon wasn’t around, David might have drowned his sorrows to the point of oblivion by now. Jon tries his best to help his friend stay on the right path and find happiness, so it’s unfortunate that David doesn’t listen to him. …Come to think of it, I probably gave him the last name \"North\" because he’s like a compass for David. My naming sense is not always the best… Anyway, Jon had his memories of the South Shore Killer case mostly erased, so it’s not really his fault at the end. If he’d known that Elena was in the building all along, he definitely would have put his life on the line to try and protect his friend."
    nvl clear
    rain_nvl "Now we get to the McMillans… Let’s talk about Avery for a bit first. He profoundly affected David’s life. Even though he’s dead for the entirety of the story, I think his character has the most impact. A crazy genius obsessed with with a strange religion… Avery definitely meant for all this to happen. He more or less instructed his impressionable young daughter to go after David in the future and he planted the seeds of doubt in David’s mind that would ultimately be his downfall."
    extend "\n\nElena picks up right where Avery left off. It’s not totally obvious, but she’s the one who killed the Jenson boy at South Shore, possibly with the help of her brothers. Our pretty little psycho killer… I tried to leave lots of hints of steadily increasing obviousness as the story wore on—her identity is especially obvious in the True Ending, but that’s the whole point. She has green eyes like her father and even her fake last name is a clue. Cormac/Cormack was the bishop son of Aibertach, a prince who started the McMillan clan—which is where the surname comes from."
    nvl clear
    rain_nvl "Unlike her father, however, Elena has a bit of a conscience—she just hides it well. In the true ending, she hesitates when it comes to David and it’s obvious she has a bit of a crush on him. I suspect that he wasn’t the horrible villain that she remembered him being when she was a child and the gap threw her off. Does she kill him in the True Ending? Who knows… It’s up to your imagination and interpretation."
    extend "\n\nOnce again, thank you so much for playing the game! Auro and I really appreciate your, ah, patronage. (: Please consider telling us your opinions via the {a=http://feudal.polldaddy.com/s/elevator}feedback survey{/a} (also reachable by navigating to {b}http://bit.ly/IACoYR{/b} in your web browser) if you have time! We pore over every submitted survey and love constructive criticism."
    stop music fadeout 1
    scene black with dissolve
    
    return

label splashscreen:
    scene black
    play sound "sounds/logo.ogg"
    show logo with dissolve
    with Pause(2)
    
    hide logo
    scene black
    with dissolve
    with Pause(1.0)

    return

# The game starts here.
label start:
    
    play music rainy fadeout 0.5
    scene rain with dissolve
    
    rain_nvl "{w=0.3}Everybody’s got some skeletons in their closet they don’t want anybody else to know about. Me, I’ve got a warehouse full of ’em. When you work in a job where you get shoved into the dregs of society, where you’ve become so desensitized to the sight of a dead body that you can even joke about it… Life’s pretty bleak." with dissolve
    extend "\n\nEven now, I can remember the look on that guy’s face. It’s been burned into my head like a brand. {i}\"Please,\"{/i} he said. Even after he’d killed all those people, he was still expecting mercy in his last days. He couldn’t see the angry, horrified looks on the faces of the people around him—had no concept of the fact that what he’d done was wrong."
    extend "\n\nThat was the first time in my life that I realized—first time it finally hit home—that there are people in the world like that—twisted psychos who think they’re the heroes and everyone else is believing in the wrong God."
    nvl clear
    rain_nvl "I couldn’t sleep for days after he was executed. Did I feel bad for him? I don’t know. I don’t think so, but nonetheless sometimes I catch myself wondering if maybe he was right all along and I’ve just been strung along with everyone else. Pretty fucking morbid to be curious about a serial killer’s God, huh? But in all my life, I’ve never felt as sure of myself as he always did."
    extend "\n\nSince that case was my \"big achievement\", the pinnacle of my career, it was the one memory the force let me keep. Awfully nice of them, isn’t it, letting me relive that time over and over…? The look on his face every time he talked to me, his eerie grin as he was being executed… I don’t even remember why it matters anymore, just that it happened. …Yeah, it definitely happened. Sometimes I almost forget."
    stop music fadeout 1
    scene office night light
    extend "\n\n…I have a warehouse full of skeletons, but they’re all in locked boxes now except for the one. And maybe it’s better that way."
    nvl clear
    window show
    "{w=0.5}{nw}" with dissolve
    j "Oh, you’re still here?" with dissolve
    play music distrust
    d skeptical "Yeah, what’s the problem?"
    j "Nothing, you just usually clock out and go home by now."
    d normal "I’ve got some stuff I still need to take care of."
    d smile "Crime never sleeps."
    j "Ha. For the Jenson case?"
    "I let out a sigh. The Jenson case is the big one that we’ve been hacking away at for the last two weeks—missing boy. Possible kidnapping, but with no ransom message after weeks, we’re skeptical. Still haven’t made much progress on finding him."
    d annoyed "…I feel like I’m missing a—a detail somewhere. Are you sure this is everything?"
    "I gesture at the computer screen and it automatically opens a holographic array of all the information Jon’s gathered so far."
    j "Dave, I’ve gone dumpster-diving for some of that. If there’s anything else, I sure as hell won’t be able to find it."
    d "Damn… Sorry, I know it’s not your fault, but it’s hard answering the parents’ phone calls every day and having to tell ’em we haven’t found their boy yet."
    j "I know… Sorry. I hate these missing people cases more than anything. Seems like 80%% of the time, they just end with a dead body."
    d skeptical_open "Awfully optimistic of you."
    j "Yeah, well, give me something to be optimistic about. Don’t stay here too long, Dave, or the elevator girl’ll worry about you!"
    d normal "I never run into her on my way out."
    j "You never know… One of these days she might catch on to your work schedule. …Well, guess I’m heading out. Gotta catch the skytram now or I’ll have to wait for the 8 o’clock one."
    d smile "All right. See you tomorrow, Jon."
    play music untold fadeout 1
    "Once he’s gone, I sigh some more. This job never gets any easier. Years ago, I was in the city’s volunteer militia. Ended up getting hired to work for the district police in the homicide department. It was rough work, but I enjoyed laying the minds of the victims’ families to rest."
    "…I think. Honestly, I don’t remember much about what went on back then. Once I started working for the district, I got a chip implanted in my brain to improve cognitive function. I developed a photographic memory and an almost perfect recall system."
    "But at the ends of big cases—especially ones where district corruption was involved—I had most of my memories of the case wiped. It wasn’t just me—it was corporate policy. All the detectives had it done. I didn’t mind it too much back then."
    "At times, I even thought it was great to not have to remember the bad things. I could just focus on the task at hand."
    "…Guess I should go, too. I’m not getting anything else done in this office, that’s for sure."
    scene elevator doors with dissolve
    "Our office is on the 78th floor of this building, a run-down place on the far east side of town. Even the elevator’s old technology—I have to wait ages for the elevator to reach me now since Jon just took it all the way to the ground floor. Hell, he might not even be there yet."
    "But forgetting the bad things… Yeah, I used to think nothing of it. All the blood, the killing, the torture, the rape… I could forget about those times and move on with a clear conscience."
    "………And then there was the case of the South Shore Killer—so called because his victims were all people whom he caught at the nearby stretch of beach. They were all tortured viciously and then murdered for their trouble."
    "By the time I caught him, he’d murdered 46 people there—that we knew about. There were many reasons to believe that he’d killed other people in other locations, too, before he settled on the South Shore, but we could never implicate him for it and he’d never confess."
    scene black with dissolve
    stop music fadeout 0.5
    "Avery McMillan. I’ll never forget that bastard’s name. Couldn’t even if I wanted to."
    
    scene office day with dissolve
    play music casual
    "We did end up finding the Jenson kid, thank God. He just wandered back out of nowhere—dazed, but without a scratch on him. Jon found him and brought him home and that was that."
    j "I still can’t believe that happened. You think he just ran away from home?"
    d normal "Maybe. He says he doesn’t remember anything that happened over the last few weeks, though."
    j "Yeah… I hope nothing happened to him. I told the parents they should have him checked out at the hospital."
    d annoyed "I doubt they will… It costs way too much in this district."
    j "Can’t they just go to another district?"
    d normal "………"
    j "Dave?"
    d surprised "Huh? Oh, sorry. Yeah."
    j "…You should get some sleep. I don’t even know why you showed up to work today—not like we’ve got other cases to work on."
    d normal "………"
    j "Unless you really did show up just to see the elevator girl!"
    d angry_open "The hell!?"
    j "I think you like her more than you’re letting on…"
    d annoyed "………"
    "\"The elevator girl\", huh?"
    window hide
    scene elevator
    show elena side
    with dissolve
    $ renpy.pause(1.5)
    scene office day
    with dissolve
    window show
    "…Jon thinks too much. I’m practically twice her age. Still, it’s strange how she just…became part of my life so easily. Without even trying." with dissolve
    scene elevator with dissolve
    play music distrust fadeout 0.7
    "It all started a few months ago. …No, I guess I have to go back farther than that."
    #window hide
    #scene rain with dissolve
    rain_nvl "{w=0.6}17 years ago, I became famous practically overnight after my team apprehended the South Shore Killer. Avery McMillan was the worst serial killer anyone had ever seen since the Green River Killer centuries back, so I shouldn’t have been surprised." with dissolve
    extend "\n\nStill, I wasn’t used to the attention—not by a long shot. Up to that point, I’d had most of the memories of my cases systematically wiped. I didn’t care about taking credit for my deeds—I’m a born introvert and I didn’t get into that line of work for the fame."
    extend "\n\nBut the district wouldn’t let me forget about this one. Everywhere I went, my face was rubbed in it. I’d done some shady things to catch McMillan—I had to. The man was a genius. A crazy son of a bitch, no doubt, but a genius. I barely caught him and it sure as hell wasn’t because he was getting messy like the public still believes to this day."
    nvl clear
    rain_nvl "I couldn’t handle all the attention—the pressure. All I wanted was to do my job. Being called a hero because I’d banded with the mafia to hunt one man down and ultimately kill him… It left a bad taste in my mouth. The higher-ups hated how I criticized them for their mistakes; I said to the press—maybe unwisely—that we could’ve solved the case sooner if certain members of the district council had been more cooperative. They had to shut me up, so I was promoted, kept away from serious cases, and expected to hobnob with the upper echelon… It wasn’t me. I had to get out of there."
    extend "\n\nSo I left the district police force and my best friend, Jonathan North, left with me. We moved ourselves into the east part of the district and bought some cheap space in an old building to use as our office—our private detective agency."
    scene elevator 78
    extend "\n\nWe’ll take any case as long as it’s something we believe in. Our place is just one little speck of idealism left in this lousy, fucked-up district."
    play music untold fadeout 1
    "{w=0.5}Even though this building has more than 80 floors, most of them are empty. Most places nowadays are more high-tech and fancy—this skyscraper’s a relic of a bygone age. But hey, the rent’s dirt cheap, so I won’t complain." with dissolve
    "There’s a pharmaceuticals place with an office somewhere in the 40’s and some other research facility somewhere… Well, I actually don’t know much about who else is in the building."
    "It’s Jon’s job to be on top of that sort of thing. It’s not something I have to bother about since it has nothing to do with my job. For years, I was perfectly fine not thinking about the other tenants and what they do here."
    "That’s what I thought…"
    scene elevator
    show elena side
    with dissolve
    "Until {i}she{/i} started showing up."
    "A young girl in her 20’s—the prime of life. I was about that age back when I was still a starry-eyed recruit at the police force. It’s pretty rare seeing someone this young working in this part of town. Most of us settle here because we can’t go anywhere else."
    "An intern? A temp? My mind came up with a quick explanation and settled for it—the girl didn’t matter to me."
    show elena normal_up with dissolve
    $ renpy.pause(0.35)
    show elena side with dissolve
    "That first day, I caught her glancing at me a few times. She didn’t look nervous at all—maybe just a little curious. I don’t exactly look like a researcher, which is what most of the people in this building do, so she was probably just caught off-guard."
    scene elevator 78 with dissolve
    "But we didn’t make any conversation at all during our time together and she quietly got off the elevator once it reached the 54th floor."
    d normal "So there’s another office on floor 54…"
    "I muttered to myself once she was gone, but that was all. The only reason I even remember this brief, insignificant moment is because of the fact that I can’t forget things once they’re in my head—not anymore."
    "After that, I began to see her in the elevator every morning. Rain or shine, weekday or not, if I was in the elevator going to work, so was she. I can’t think of a single time when she wasn’t there with me after the first time—even to this day."
    "For the first several days, we didn’t speak to each other at all. I guess either she’s as much of an introvert as I am or we just didn’t have anything to say to each other. I could’ve made conversation if I really wanted to, but I didn’t, so… I didn’t."
    scene elevator
    show elena side
    with dissolve
    $ renpy.pause(0.35)
    show elena normal_up with dissolve
    $ renpy.pause(0.35)
    show elena concerned_closed with dissolve
    $ renpy.pause(0.5)
    show elena side with dissolve
    d skeptical "(…She’s looking at me again. But what’s with that face she’s making?)"
    show elena normal with dissolve
    e1 "………"
    show elena concerned_open with sdissolve
    e1 "Excuse me…"
    show elena concerned_closed with sdissolve
    d surprised "Yes?"
    "I was surprised she was talking to me. She had a nice voice, edged with concern though it was."
    show elena concerned_open with sdissolve
    e1 "Your shoulder…"
    d normal "What about it?"
    e1 "There’s blood seeping through your shirt. I can sm—I can see it from here."
    d "(Huh. What a sensitive girl she is.)"
    d teasing "Sorry. Happens a lot in my line of work."
    show elena surprised with sdissolve
    e1 "Your line of work?"
    d normal "I’m a detective. I had to apprehend a runaway last night and he gave me some trouble."
    show elena concerned_open with sdissolve
    e1 "A runaway… A criminal that tried to run?"
    d teasing "It wasn’t anything {i}that{/i} glamorous. A runaway cat."
    show elena surprised with sdissolve
    $ renpy.pause(0.35)
    show elena smile with sdissolve
    play music casual fadeout 0.7
    e1 "…Ha! I see. Sounds like you had a rough night."
    d smile "I’ve definitely had better."
    "The strange tension that had always been there between us lifted after that."
    show elena surprised with sdissolve
    e1 "Oh! Sorry, I’m Elena. Elena Cormack."
    show elena smile with sdissolve
    e "I’ve seen you every day, but I’ve never introduced myself, huh? Sorry for being so forward."
    d normal_open "Don’t worry about it… I’m not exactly the type to stand on ceremony."
    d "I’m David Carmichael. Good to meet you."
    show elena normal_up with sdissolve
    e "So there’s a detective agency on the 78th floor… I had no idea."
    d normal "Well, we’re pretty quiet and we don’t bother the other tenants here much. Most people don’t know about our agency unless they actively look for it."
    show elena normal_open_up with sdissolve
    e "I see… Well, we have some time before this elevator reaches my floor, so why don’t I take care of that—ah—wound of yours?"
    d surprised "There’s no need to—"
    show elena smile with sdissolve
    e "Come on, don’t stand on ceremony, Detective Carmichael!"
    d annoyed "…Fine. Kids these days."
    hide elena with dissolve
    "Elena pulled a small first-aid kit from her jacket pocket while I rolled up my sleeve. She had the wound taken care of in no time at all."
    d normal "So I take it you work for the pharmaceutical company here?"
    show elena surprised with dissolve
    e "Why would you think that?"
    d skeptical "Why else would you have a first aid kit?"
    show elena normal with sdissolve
    e "Actually, I’m a secretary at a travel agency—the Pluma agency. I carry around this first aid kit because it’s company policy."
    d normal "Huh… Do people get injured enough at your office to warrant that?"
    show elena skeptical_open with sdissolve
    e "You’d be surprised how much trouble people can get themselves into with a paper cutter or a letter opener."
    d skeptical "That’s… Amazingly sad. But I guess my saying that is like the pot calling the kettle black."
    show elena concerned_open with sdissolve
    e "The pot… Huh?"
    d teasing "…Damn, the age difference is showing. It’s an old phrase. I was saying that I shouldn’t make fun of them when I got this much damage from a cat."
    show elena smile with sdissolve
    e "Ha! I see."
    play sound elevatording
    scene elevator 78
    show elena surprised
    with sdissolve
    e "Oh, this is my floor. It was nice talking to you, Detective."
    hide elena with dissolve
    "So that’s how it started. From then until now—a good seven months or so—the two of us have been—well, {i}elevator buddies{/i}, I guess. Maybe \"buddies\" is taking it a little far. Anyway, we don’t always talk up a storm, but she’s always there."
    scene office day with dissolve
    "She’s a pretty girl, no doubt, but Jon’s got it all wrong. Hell, I’m practically old enough to be her father. Some of the things I say are so old-fashioned that she doesn’t even understand them. That’s not exactly reassuring."
    j "These days, a lot of women are interested in a stable older man, you know. You should seize the chance to snag yourself a hot younger wife."
    d skeptical "You haven’t even seen her yet."
    j "Sure, but if she was unattractive, you wouldn’t have brought her up at all, right?"
    d annoyed "You think I’m that shallow?"
    j "Aren’t we all a little shallow?"
    "I sigh. Jon’s got the idea that I need to settle down and find normal happiness. \"We’re already at that age,\" he’s always saying. Over the hill. Middle-aged. Past the prime of life. All the more reason a girl like Elena’d never be interested in an old-timer like me."
    d normal "Well, I’ll think about it."
    "Hopefully that’s enough to shut him up."
    nvl clear
    play music rainy fadeout 1
    rain_nvl "{w=1.3}McMillan’s staring down the barrel of my gun—I can see it in my mind clear as day if I close my eyes. I could’ve shot him from a distance, but I just wanted for him to get a taste of what it was like for his victims to be face-to-face with death. Would he tremble? Would he be just as afraid as they were?" with fade
    extend "\n\nIn the end, I think he felt nothing at all. He stared at me impassively with those bottomless green eyes of his and just smiled. This wasn’t the reaction I’d wanted. I roared at him to surrender, to tell me why he’d killed all those people. I’d been chasing this bastard for what seemed like forever—I needed closure, I needed answers."
    extend "\n\n\"Killed?\" He looked offended at my choice of words. \"I was just returning them to God.\""
    extend "\n\n\"God doesn’t need you doing him favors!\" I said back to him. I was disturbed by how peaceful he seemed even as I held his life in the palm of my hand."
    nvl clear
    rain_nvl "\"Your God and mine are not the same.\" There was that smile again, completely without malice. He really believed what he was saying and he saw nothing wrong with his logic."
    extend "\n\nWell, of course he didn’t. If he did, he wouldn’t have committed those crimes."
    extend "\n\nI had nothing to say to him. I just wanted him to admit that what he did was wrong, to feel some shame… Or to even be upset that he was being taken in. He did none of those things. The only time he showed any emotion at all was when his family got involved during the trial."
    extend "\n\n\"I’d like for my children to be protected… I think some might give them a hard time because of all this.\" He looked troubled. Was this an admission of guilt over his actions? He clearly understood that his family could get lynched for what he’d done, at least. So I asked him. \"It’s certainly not {i}my{/i} fault that this is happening to them.\" McMillan seemed disgusted that I’d even imply it. \"It’s not my fault nobody else understands our God.\""
    nvl clear
    rain_nvl "\"Our God\" he said, but his family denied it—their official statement claimed that they had no knowledge of his actions and did not condone any of what he did. They abandoned him even as he was worrying about how the public might crucify them."
    extend "\n\nI can still remember his youngest child staring at me when I was on the stand, but her face was unreadable. She probably wasn’t old enough to understand any of what was going on… God. Why did her father have to put her in this position? I wondered if she would have to change her name or move…"
    extend "\n\nAnd then I felt annoyed that we had to protect his family at all. To follow his wishes even though he’d ignored the wishes of at least 50 people who didn’t deserve to die."
    stop music fadeout 1
    scene elevator
    extend "\n\n\"I am returning to Ashura.\" Those were his last words. They brought me no comfort at all."
    nvl clear
    "{w=1}Another{nw}" with fade
    play music casual
    extend " morning, another 20-minute ride up the elevator. I’ve heard that this is slow even by \"ancient relic\" standards, but I have nothing to base it on and it’s not like we have any mechanics who’ll fix something like this up."
    "20 minutes is just enough time for me to collect my thoughts… Or let my mind wander back to the past and what I remember of it."
    "…Usually it’s the second one."
    show elena side with dissolve
    "Elena’s here again—of course she is. She looks like she’s deep in thought."
    menu:
        "Greet her.":
            $ elena_pts += 1
            d normal "Good morning."
            show elena surprised with dissolve
            e "Oh! Good morning, Detective."
            show elena smile with sdissolve
            e "Sorry, I was lost in my thoughts."
            d "I could tell. Got a problem at work? You seem a little more tired than usual."
            show elena surprised with sdissolve
            e "Huh? Tired? How do you figure?"
            "I point at her shoulders."
            d skeptical "Your shoulders are sagging. Normally your posture’s beyond reproach."
            show elena surprised_closed with sdissolve
            e "I’m amazed you noticed something like that…"
            show elena smile with sdissolve
            e "I suppose that’s what being a detective is all about, though. I bet you can tell all sorts of things about a person just by looking at them."
            d normal "These days, not so much. I’m just getting used to you."
            e "Ha! There you go being modest again."
            scene elevator 78 with dissolve
            "Elena and I make a bit of small talk before we reach her floor and she says goodbye."
        "Leave her be.":
            d normal "………"
            "I don’t have anything I really need to talk to her about and she looks pretty preoccupied, so I suppose I’ll just leave the girl alone."
    scene office day with dissolve
    "Work is pretty slow these days, but I can’t complain. It just means people aren’t getting in trouble as much this week. The less dead bodies me and Jon have to find, the better."
    j "So how was she today?"
    "He really is pretty nosy, especially when there’s nothing else for him to do but bother me about my nonexistent love life."
    if elena_pts > 0:
        d skeptical "She was fine. Seemed a little tired."
        j "You noticed something like that?"
        d normal "It was pretty obvious."
        "…Is what I say, but maybe I {i}am{/i} too conscious of her. Well, when it’s just two people in a little elevator day after day, you can’t help but notice each other, I guess."
    else:
        d normal "She’s fine, I guess. We didn’t talk today."
        j "Letting her pass you by, eh?"
        d smile "That’s the way it should be. She should mingle with guys from her own generation."
        j "You don’t give yourself enough credit."
        d skeptical "And you give me too much."
    
    play music mystery fadeout 1
    j "Anyway, jokes aside, I got some disturbing news today. Pretty nasty stuff."
    d annoyed "…What is it?"
    j "The Jenson kid we found last week… He’s dead."
    d angry_open "What!? What the hell happened?"
    j "He was killed. …On the South Shore."
    "My blood runs cold when I hear those last two words. The \"South Shore\"… Avery McMillan… I put the thoughts out of my head. McMillan’s dead and plenty of people go to South Shore now. Accidents—even the occasional murder—happen every day."
    "I try to calm down before my paranoia affects my judgment."
    d normal "Are we being put on the case?"
    j "No, the police are taking care of it. The parents just wanted to update us since we worked so hard on finding him. It seems they were there on a family outing."
    j "The boy disappeared from their sight for a few minutes and then he was found washed up on the shore—dead. God, you’d think they would keep a better eye on him after he vanished the first time."
    d annoyed "It’s not their fault… No one expects these things to happen."
    j "Yeah… Sorry to be the bearer of bad news, Dave."
    d normal "Don’t blame yourself. It’s just a tragedy… I hope the police can catch him."
    j "They’ve never done half as well on homicide cases since you left… But yeah, I hope so, too."
    stop music fadeout 1
    "Hell… What is the world coming to?"
    scene elevator doors
    with dissolve
    play music distrust
    "The next morning, I’m waiting in the lobby for the elevator to come down to the first floor. The Jenson case floats to the forefront of my mind and I sigh."
    e "Had some more trouble with a cat?"
    "Elena. I hear the click-clack of her high heels against the tile floor as she walks up to me and stands at my side. I sigh again."
    d annoyed "I wish it was as simple as that."
    play sound elevatording
    scene elevator wall
    show ed2:
        xalign 0.0
    show ed1:
        xalign 0.0
    with None
    $ renpy.pause(1.0)

    show ed2:
        xalign 0.5 xanchor 1.0 # pic_1 will be placed at left offscreen
    show ed1:
        xalign 0.5 xanchor 0.0
    with MoveTransition(2.0)
    
    "The two of us step onto the elevator together, press the buttons for our respective floors, and settle in as usual."
    scene elevator with dissolve
    show elena concerned_closed with dissolve
    e "………"
    d normal "What is it?"
    e "Well, I feel like I shouldn’t ask what you’re so upset about, but I do want to know…"
    d surprised "Why do you feel like you can’t ask?"
    show elena normal_open with sdissolve
    e "Don’t detectives have some sort of confidentiality agreement with their clients? It wouldn’t do for me to pry."
    "Oh, I see. That’s actually a pretty legitimate concern. Elena’s a lot more thoughtful than I give her credit for."
    d normal "…Actually, this time I’m worried about something the whole district knows about… That murder that happened on the South Shore yesterday."
    show elena concerned_closed with sdissolve
    e "Oh… That. I heard about it, too… What an unfortunate incident. His family must feel awful."
    d annoyed "No doubt. And after they’d just been reunited, too…"
    show elena surprised with sdissolve
    e "Reunited?"
    "Shit. The boy’s disappearance wasn’t public knowledge. Me and my big mouth. …I’m {i}never{/i} this careless. Not usually. Something about this girl just lowers my guard. It must be those big, innocent eyes and how she’s so easy for even an old man like me to talk to."
    menu:
        "Cover up for myself.":
            d surprised "Oh… I mean, it was the first time in a while that the family had gone to the beach, right? That’s what I heard."
            show elena concerned_open with sdissolve
            e "Oh… That’s so sad. Imagine someone you love being killed while you were out relaxing together…"
            hide elena with dissolve
            "There’s sort of an awkward tension after that, so neither of us say anything more to each other before we part ways."
        "Just go ahead and explain.":
            $ elena_pts += 1
            d normal "…To tell the truth, the boy actually disappeared once a few weeks ago. My partner and I were hired to find him."
            e "You mean to say something happened to him even before this?"
            d "Yes. After a few weeks we found him, but he had no memory of what happened while he was gone…"
            d annoyed "At any rate, we were just satisfied that he could be reunited with his family, but then this happens…"
            show elena concerned_open with sdissolve
            e "That’s so sad… I can’t even begin to imagine how his family might feel right now."
            show elena surprised with sdissolve
            e "Oh! But is it alright for you to be telling me all this?"
            d normal "I can’t see that it would hurt anything… Just don’t go blabbing about it to anyone, I guess."
            d smile "I can trust you with that much, right, Elena?"
            show elena smile with sdissolve
            e "Of course you can, Detective!"
            show elena hmph_open with sdissolve
            e "{size=-8}…I don’t really have anyone to tell, anyway.{/size}"
            d surprised "What do you mean?"
            show elena surprised with sdissolve
            e "Hmm? Oh! Sorry, it was nothing."
            show elena side with dissolve
            "What a peculiar girl… I wonder if, like me, she feels alone at times. She wouldn’t have said it like that if it wasn’t something that bothered her, right?"
    scene office day with dissolve
    play music casual fadeout 1
    j "So how was the elevator girl today?"
    d annoyed "You seem awfully concerned about her, Jon."
    "As usual, I suppose."
    j "Haha! You think so? It’s just that I never see you interact much with anyone but me, so I guess I’m just happy that you’re widening your horizons a little."
    d skeptical "Making small talk with someone on an elevator is considered \"widening your horizons\" these days?"
    j "Eh, I’ll take what I can get."
    d normal "Is there any news on the Jenson case?"
    j "…Nope. It’s only been 24 hours, after all."
    d annoyed "I see…"
    j "………"
    "When Jon doesn’t say anything, I look up and am surprised to see him look so worried. This guy’s normally the balancing act to my infinite pessimism, after all."
    d surprised "What’s the matter with you?"
    j "I’ve been thinking… Maybe you shouldn’t worry so much about this case."
    play music mystery fadeout 0.5
    d angry_open "Huh!? What do you mean by that?"
    j "It’s got some parallels to the South Shore Killer case, right? You were really out of it back then… Before and after McMillan was caught. I think it’s best if you keep your mind off all this. You dwell on that case too much as it is."
    d annoyed_open "Wha… I don’t dwell on it!"
    j "Are you kidding me? You think about it every day! Don’t try to lie to me, Dave, I know you better than anyone. Who was your partner on that case?"
    d annoyed "………"
    "I hate to admit it, but Jon’s right. I do think about the McMillan case a lot. But can he blame me? It’s not as if I have many other memories to think about… The force took them away from me for better or for worse."
    d annoyed "And what’s wrong with thinking about it?"
    j "It’s unhealthy, that’s what. It’s been almost 20 years since he was executed. He’s not here anymore, the killing’s stopped. So why are you still acting like he might pop out from around the corner at any given moment?"
    "…That’s not what I worry about. That’s not it at all. But how do I explain my thoughts to Jon? I don’t even understand it myself…"
    play music rainy fadeout 1
    rain_nvl "{w=1.3}Ashura… In an ancient language, it meant \"whole heaven\". Ashura slayed Tiamat—the embodiment of chaos—and created the world of man. He’s usually shown as being a warrior and representing the sun." with fade
    extend "\n\nThe God Avery McMillan believed in wasn’t some Satanic war god or anything like that, but a God that apparently created the world."
    extend "\n\nNot many people believe in any God anymore. While science hasn’t exactly disproved the existence of one just yet, people nowadays are more concerned with the here and now than the hereafter."
    extend "\n\nEven while on the stand at his own murder trial, McMillan preached about his God. For whatever reason, he truly believed that what he was doing was right. He tortured people when they couldn’t accept his truth. He killed them once they did because then they’d be reunited with Ashura."
    nvl clear
    rain_nvl "I wonder if his victims died peacefully, accepting a God that only existed in the mind of a delusional murderer. The thought makes me want to throw up."
    extend "\n\nWhy do I always think about the South Shore Killer case? I caught the guy. Tests and examinations showed that he was definitely not in his right mind. Good triumphed over—not evil, exactly, but the killing of innocents, at least."
    extend "\n\nMcMillan did say that his victims were innocent. In fact, that was why they were chosen. To populate the kingdom of Heaven with good souls. How he chose his victims, even now, is a mystery to me. Though he talked endlessly about Ashura and about his family, McMillan never revealed specifics about his methods or about his victims. People begged him to reveal if he’d killed others—where he’d hidden bodies that were never found. But he never did."
    nvl clear
    rain_nvl "\"My family, Detective Carmichael… You have to make sure that they’re safe.\" I was in a cruel mood that day, so I simply said that I could make no guarantees. McMillan stared blankly at me for a few moments before grinning. \"Well, it’s alright if you don’t, though you will have points subtracted. It would have been nice for them to live a bit longer, but Ashura will decide when it’s time for them to come to me.\""
    extend "\n\nThat was it. As much as I wanted him to know how guilty he was, as much as the families of the dead wanted him to suffer, he never did. He accepted his death almost happily and when he was gone, there was no closure."
    extend "\n\nNot for the victims’ families… Definitely not for me."
    nvl clear
    rain_nvl "God. I think that’s the problem. Catching him and watching him die did nothing to make me feel like my ideals held true. Even though he died, I don’t feel like he paid for his crimes… And even now, I’m not at peace with the world or with myself—but he was."
    extend "\n\nDoes that mean I was wrong? …But how could I be wrong? And yet, if I was right, why aren’t I happy? Why don’t I feel proud about what I did?"
    stop music fadeout 1
    scene elevator
    show elena side
    extend "\n\nMcMillan was insane. No doubt. But these nagging worries I have, little thorns in my chest, are a sort of madness, too…"
    nvl clear
    "{w=1}Elena’s{nw}" with fade
    play music distrust
    extend " being quiet today."
    "I wonder if I’m projecting my bad mood onto her… She never bothers me whenever I stand here with a scowl on my face."
    play sound elevatording
    scene elevator 78
    show elena side
    with sdissolve
    $ renpy.pause(1)
    hide elena with dissolve
    "Not like I {i}have{/i} to talk to her. Sometimes a whole week goes by where neither of us say anything except \"good morning\" and \"goodbye\"."
    "She’s a young woman in the peak period of her life and I’m a dried up old man. …Okay, Jon would get on my case for that. \"You’re barely in your 40’s! If you’re an old man, it means I’m one, too, and I’m sure as hell not getting into that boat with you!\""
    "Still. There’s a limit to how much she can humor me with conversation—or how much I can bore her with it."
    play music casual fadeout 1
    scene office evening with dissolve
    "A few quiet weeks go by. A young man gets apprehended for the Jenson murder and confesses to the crime. Says it was an impulse. What a goddamned awful impulse to have… My bad mood passes and things get back to normal."
    j "You’ve got some color on your face today."
    d skeptical "You think so?"
    j "Yeah. Good for you, Dave."
    "…I don’t feel particularly happy or anything, but I guess anything above \"depressed\" is a pretty good state to be in."
    j "—Elevator girl must’ve said something nice to you today!"
    d skeptical_open "………"
    "I don’t bother replying. If I so much as sneeze, Jon’ll think Elena’s involved somehow."
    scene office night light with dissolve
    "Jon clocks out around seven or so and I leave a couple hours later once all my work’s done."
    scene elevator 1 with dissolve
    "I know I shouldn’t think like this, but peaceful times worry me—you know Murphy’s Law? All the time, I feel that if I let my guard down, all hell will break loose when I least expect it."
    scene black with dissolve
    "Come on, David, don’t think about this stuff… I close my eyes and try to think about something more positive. A warm breeze, white sandy beaches—shit, I shouldn’t think about the beach…"
    play sound elevatording
    "Oh, someone’s leaving at the same time as me? Must be someone from the pharmaceutical company… They’re the only ones who ever seem to keep late hours like I do. I’ve run into the scientists a couple of times."
    scene elevator 1
    show elena surprised
    with dissolve
    e "Oh, Detective Carmichael!"
    d surprised "Elena! What are you—"
    "I cut myself off, feeling foolish. Obviously she’s leaving work just the same as I am."
    d normal "I’ve never seen you leave this late before."
    e "Well, I normally leave earlier, but…"
    show elena hmph with sdissolve
    e "I made a mistake at work today and it took some time to fix everything."
    d skeptical "What kind of mistake had you there this late?"
    show elena defiant with sdissolve
    e "I miscopied some papers… Well, to be fair, I was just following orders. I ended up taking the fall for a superior’s mistake."
    d normal "Sounds pretty rough."
    show elena normal with sdissolve
    e "It’s nothing compared to what you do, I’m sure. Do you usually leave this late?"
    d "Something like that. I don’t like leaving things half-done."
    show elena smile with sdissolve
    e "Ha, I can believe that. You seem like the meticulous type."
    d surprised "You think so?"
    e "Sure."
    scene rain with dissolve
    play music untold fadeout 1
    "Once we reach the lobby, we can see the heavy rain outside."
    d annoyed "Damn… I didn’t bring an umbrella."
    if elena_pts == 2:
        e "…He must be crying today."
        scene elevator doors
        show elena concerned_closed
        with dissolve
        d surprised "What?"
        show elena surprised with sdissolve
        e "I’m sorry?"
        d normal "You just said that someone must be crying today. \"He\". What did you mean by that?"
        show elena concerned_closed with sdissolve
        e "Oh… It’s nothing, really, just something I…"
        show elena regret with sdissolve
        "She trails off. I’ve never seen Elena this melancholy before."
        menu:
            "Press her for details.":
                d skeptical "Well? What is it?"
                show elena hmph with sdissolve
                e "It’s nothing, really, Detective. I was just thinking out loud."
                "Awkward minutes pass by like hours, but she won’t say anything more on the subject."
            "Wait for her to continue.":
                $ elena_pts += 1
                "There’s no point in forcing an answer out of her if she doesn’t want to tell me. With the rain this heavy, I’m not exactly keen on rushing out into it, so I can afford to wait."
                "After some silent moments pass by, Elena finally decides to continue."
                show elena concerned_closed with sdissolve
                e "Promise you won’t laugh."
                d skeptical "Not a hard promise for me to make."
                show elena concerned_open with sdissolve
                e "When I was little, my father died."
                d normal "…I’m sorry to hear that."
                show elena side with dissolve
                e "But before he did, he told me something… He said he’d always be with me even if I couldn’t see him. He said that if it’s sunny, it means he’s smiling down at me."
                d "And if it’s raining, it means he’s crying?"
                show elena normal with dissolve
                e "Something like that."
                show elena regret with sdissolve
                e "I never could stand it when my father cried, even then. I wonder what he’s sad about today."
                "A man who had no shame in crying on front of his young daughter? That’s pretty impressive in its own way."
                d smile "Sounds like you had a very sentimental father."
                show elena smile with sdissolve
                e "Haha. Yes, he was just that kind of person. He stuffed me and my siblings’ heads full of stories. Even now I remember a lot of things he told me and hold our memories close."
                show elena side with dissolve
                e "I suppose it’s childish of me to believe in such things, but to forget would be disrespectful. To forgive would be even worse."
                d "Your father really cared about you… It’s obvious that he raised you well, seeing what a good person you are now."
                show elena smile with dissolve
                e "Thanks, Detective. That’s grand of you."
        show elena normal_up with dissolve
        e "Well, it looks like the rain’s letting up, so I won’t keep you any longer."
        d normal "See you tomorrow?"
        show elena surprised with dissolve
        $ renpy.pause(0.35)
        show elena smile with dissolve
        "I’ve never said such a thing to her before… But it just feels right, somehow, to say it tonight. Does it make me sound too eager? Is it foolish of me to feel like this young woman and I are building rapport?"
        e "Yes, I’m sure you will. We’re making a habit of running into each other, aren’t we?"
        d skeptical "I’d say we already made that habit months ago."
        e "I guess you’re right, Detective. Well, see you tomorrow, then!"
        hide elena with dissolve
        stop music fadeout 1
        "\"I guess you’re right, Detective.\" Weird, I’m feeling a sense of deja vu… Was it from that? Well, Elena and I have talked a lot over the last few months. No doubt she’s said that to me before."
    else:
        show elena smile with dissolve
        e "I’ll see you later, Detective! Try to stay dry."
        d smile "Thanks, Elena. You, too."
        stop music fadeout 1
        hide elena with dissolve
        "I’m not sure I can keep my word on a night like this, but I make a mad dash for the skytram station anyway."
    if elena_pts == 3:
        jump true_ending
    else:
        jump normal_ending


label normal_ending:
    scene elevator 78 with dissolve
    "The next{nw}"
    play music casual
    extend " day rolls around… I get the feeling that I had bad dreams last night, but I don’t remember them. Typical."
    show elena normal_up with dissolve
    e "You seem troubled today, Detective."
    show elena surprised with sdissolve
    e "You didn’t catch a cold from the rain, did you?"
    d surprised "No, nothing like that…"
    d normal "I had some trouble sleeping, that’s all."
    show elena concerned_closed with sdissolve
    e "I see. That’s too bad."
    "I’m about to reply when I notice that we’ve gone well past the 54th floor already. It’ll be my stop soon enough."
    d surprised "Wait, we’ve passed your floor!"
    show elena surprised with sdissolve
    e "What? …Oh no! I know I pushed the button for my floor… I must have not used enough force."
    d normal "Sorry you have to wait a while longer."
    show elena smile with sdissolve
    e "It’s alright. I’m in no rush."
    play sound elevatording
    scene elevator blank
    show elena surprised
    with sdissolve
    e "Oh! Looks like it’s time for you to go."
    show elena smile with sdissolve
    e "See you tomorrow, Detective."
    d normal "Yeah, maybe."
    show elena surprised with sdissolve
    $ renpy.pause(0.8)
    hide elena with dissolve
    "I step out of the elevator, not intending to say anything else. I don’t want to get the girl’s hopes up or anything like that. I’m just an old man—if she’s interested in me at all, she shouldn’t be."
    stop music fadeout 0.5
    e "…Minus 100 points, Detective Carmichael."
    "Huh? Why does that sound familiar? I turn around just as the elevator doors start to close."
    window hide
    show image "Elena-smile.png" with sdissolve
    show ed2:
        xalign 0.5 xanchor 1.0 # pic_1 will be placed at left offscreen
    show ed1:
        xalign 0.5 xanchor 0.0
    with None
    $ renpy.pause(0.5)
    show ed2:
        xalign 0.0
    show ed1:
        xalign 0.0
    with MoveTransition(2.0)
    window show
    "…What was that all about?"
    play music distrust
    j "…Dave?"
    scene office day with dissolve
    d surprised "Oh, Jon."
    j "Was that the elevator girl?"
    d normal "Hmm? Yeah. That’s Elena, all right."
    j "Elena… Why does that name sound familiar?"
    d surprised "I’ve never told you her name before?"
    j "Nope. It just never came up, I suppose. Elena… Elena………"
    "I wonder why Jon seems so fixated on her name, but I’m too tired to press the issue."
    scene office night light with dissolve
    play music casual fadeout 0.7
    j "Well, see you later, Dave! Don’t stay here too late. I mean it."
    d normal "Good night. Be careful on your way home."
    j "You, too."
    d teasing "Come on, I’m always careful."
    stop music fadeout 1
    scene office night with dissolve
    "After Jon leaves, I stretch my arms above my head and sigh. Today was a long day."
    play sound "sounds/horror.ogg"
    scene black with Dissolve(0.2)
    "The electricity in the office goes out, surrounding me in darkness… I feel a pain between my ribs and then there’s nothing else."
    play music "sounds/d_34a.ogg"
    if not persistent.true_ed:
        "You have reached the {b}Normal Ending{/b}! Try playing the game again to see if you might be able to get the True Ending and shine some light on the situation…"
    else:
        "You have reached the {b}Normal Ending{/b}! Congratulations on clearing The Elevator. Please consider {a=http://feudal.polldaddy.com/s/elevator}filling out a short survey{/a} to let us know how your experience went."
    return

label true_ending:
    play music rainy
    
    rain_nvl "{w=0.25}\"You know, Detective Carmichael, I think you’ve got to be the most interesting fellow I’ve ever met in my life. I wish my children could get to know you and learn from you.\" McMillan’s talking to me again through the double-sided mirror. I don’t know how he does it, but he always knows when I’m there. With a sigh, I switch on the intercom." with dissolve
    extend "\n\n\"You want your kids to learn from the man who brought you down? I thought you were supposed to be a genius.\""
    extend "\n\n\"Think about it. They could learn more about me from studying you. You know me better than anyone, don’t you? That’s how you could catch me. You had to—ah—get inside my head. Is that the jargon?\" He sounds amused even though what he’s saying should be disturbing. \"And how did you like it?\""
    nvl clear
    rain_nvl "\"How did I like what?\""
    extend "\n\n\"The view from inside my head.\" His tone suggests that he’s offended I didn’t get his meaning immediately."
    extend "\n\n\"It was a dark place. I’d like it very much if I never had to go back there.\""
    extend "\n\n\"I suspect you never will—not after this. Hmm. You’re, what, 26 this year? …Don’t give me that look, David. If you know so much about me, don’t you think I’d read up a bit on you?\""
    extend "\n\n\"…I didn’t think you had the time for stuff like that.\""
    extend "\n\n\"Why not? I had plenty of time on my hands. Still do, in fact. I contemplate Ashura and the kingdom of Heaven constantly.\""
    nvl clear
    rain_nvl "\"It would be better if you spent that time thinking about all the innocents you killed.\""
    extend "\n\n\"Nonsense. Thinking about the dead isn’t very productive at all. I only humor you a bit during your interrogations because they won’t let me talk to you otherwise.\" He laughs heartily as if he’s just made a brilliant joke. \"If it wasn’t for you, I’d have to talk to those stuffy prosecutors all day… Very dull business, that.\""
    extend "\n\n\"And what {i}about{/i} my age?\""
    extend "\n\n\"Ah, so you {i}are{/i} curious!\" When I don’t respond right away, he looks just a little bit disappointed, but presses on nonetheless. \"I was just thinking that 26 is a nice age to be. I suspect that you have many years left ahead of you.\""
    nvl clear
    rain_nvl "\"…Before what?\""
    extend "\n\n\"Oh, before you go to Hell. It’s a shame, really. Would’ve been great fun having you in Heaven, but I’m afraid you locking me in here isn’t getting you many points with God.\""
    extend "\n\n\"………When you get there, McMillan, tell your God that I think he’s pretty fucked up.\""
    extend "\n\n\"Minus three points for vulgarity. But plus one point for starting to acknowledge His existence. Maybe you’ll make up for your negative points before you die. That would be delightful.\""
    extend "\n\nA buzzer sounds from behind me… His family’s here to visit him. They’re allowed to do so exactly once a month for about half an hour."
    stop music fadeout 1
    scene black
    extend "\n\nI can’t help but hope that what he tells them is more pleasant than what he’s always telling me."
    "{w=0.5}I awake from a dream—from a memory—covered in a cold sweat. I grope around in the darkness looking for something—anything—but grasp nothing but air." with dissolve
    "I’ve had enough of this. I don’t give a shit if Ashura is the real God—I don’t want to think about it anymore. I don’t want to remember anymore."
    "…I have work in a few hours. Better get back to sleep."
    scene elevator 78 with dissolve
    show elena concerned_closed with dissolve
    e "You{nw}"
    play music casual
    extend " seem troubled today, Detective."
    show elena surprised with sdissolve
    e "The rain didn’t make you catch a cold, did it?"
    d surprised "No, nothing like that…"
    d normal "I had some trouble sleeping."
    show elena concerned_closed with sdissolve
    e "I see. That’s a shame. You should leave work early today, then, if you’re still feeling tired. I hope work isn’t too busy today."
    d normal "Yeah… You know what? I think I {i}will{/i} do that. We don’t have any big cases to work on, anyway, so it won’t hurt anything."
    d smile "Sorry to worry you all the time. You shouldn’t bother so much with an old man like me, Elena."
    show elena smile with sdissolve
    e "Aww! I don’t think of you as an old man, Detective."
    "While I stop to think of how to respond to that, I notice that we’ve gone well past the 54th floor already. It’ll be my stop soon enough."
    d surprised "Wait, we’ve passed your floor!"
    show elena surprised with sdissolve
    e "What? …Oh no! I know I pushed the button for my floor… I must have not used enough force."
    d normal "Sorry you have to wait a while longer."
    show elena blush with sdissolve
    e "It’s alright. I don’t mind spending a bit more time with you, Detective."
    play sound elevatording
    scene elevator blank
    show elena blush
    with sdissolve
    d annoyed "I’m serious. You ought to spend some more time with fellows around your own age."
    show elena surprised with sdissolve
    "I remember the look on her face when Elena told me she had nobody to talk to… She doesn’t deserve that… Elena deserves someone who will make her feel better when it rains and her father’s crying. She doesn’t need someone like me who can’t even move on from his past."
    hide elena with dissolve
    "I step out of the elevator, not intending to say anything else. …Maybe I was a little harsh?"
    stop music fadeout 0.5
    e "…Minus 100 points, Detective Carmichael."
    "What?! I whirl around just as the elevator doors start to close."
    window hide
    show image "Elena-smile.png" with sdissolve
    show ed2:
        xalign 0.5 xanchor 1.0 # pic_1 will be placed at left offscreen
    show ed1:
        xalign 0.5 xanchor 0.0
    with None
    $ renpy.pause(0.5)
    show ed2:
        xalign 0.0
    show ed1:
        xalign 0.0
    with MoveTransition(2.0)
    window show
    "…What was {i}that{/i} all about? Did she say \"points\"?"
    play music distrust
    j "…Dave?"
    scene office day with dissolve
    d surprised "Oh, Jon."
    j "Was that the elevator girl?"
    d normal "Hmm? Yeah. That’s Elena, all right."
    j "Elena… Why does that name sound familiar?"
    d surprised "I’ve never told you her name before?"
    j "Nope. It just never came up, I suppose. Elena… Elena………"
    d normal_open "You keep tabs on the other companies in this building, don’t you? Her name probably came up once or twice."
    j "Huh. Which company does she work at?"
    d normal "Pluma? It’s a travel agency, if I remember right. She’s a secretary."
    j "You always remember right. …Pluma, huh? I don’t remember a travel agency being in this building, but I could be wrong about that. It’s been a while since I’ve checked. Which floor is she on?"
    d "The 54th floor. She missed her floor by accident today—she normally gets off before I do."
    "Jon’s eyebrows furrow in confusion."
    j "54th…? There’s no way."
    d surprised "What? Why not?"
    j "Nobody can work in the 50’s in this building. The floors’ve been sealed off for ages because of some incident from before. A fire or something… They never got around to fixing it all."
    "What…? How can that be possi—"
    j "Well, you’ve seen her get off on the 54th floor every day, right?"
    "Oh, right. I didn’t even think of that. Leave it to an old man to jump to conclusions."
    d annoyed "Yeah… Looked like a normal office hallway to me. I think I would’ve noticed if the floor was condemned."
    j "They might have fixed it up recently, then. Like I said, it’s been a while since I’ve checked."
    d normal "………"
    j "Dave?"
    d surprised "Huh?"
    d normal "Oh… Yeah, I’m sure you’re right."
    scene office night with dissolve
    play music mystery fadeout 1
    "Still, I can’t get all of this off my mind for the rest of the day. Something’s nagging at me… Something big."
    "{i}\"Minus 100 points, Detective Carmichael.\"{/i} I’ve only ever known one other person to say something like that to me. …Come to think of it, her eyes are the same color as his…"
    show image "Files.png" at left, files_pan
    "In a horrified daze, I start going through my files, pulling out all my information on the South Shore Killer."
    "I haven’t looked at these files in years. With my vivid memories, I thought there was no need to. I had Jon organize the files for me and then put them away. I even have to dust them off a bit before I sit down."
    "Avery McMillan… The South Shore Killer. Murdered almost 50 people that we know of because he wanted them to go to Heaven. He was a fanatic about a religion nobody else believed in… And I caught him. I worked with hired guns and used dirty government money to set up a perimeter and finally track him down."
    "And yet… He knew I was on his trail. Everyone always wondered why he insisted on killing people at the beach even when he knew we were on to his pattern. But even after we knew, he eluded us."
    "He would take advantage of camera blind spots or use other people as shields… It’s as if he was taunting us, declaring silently that even with our knowledge, we couldn’t catch him."
    "…In the end, though, we still did. I led the team that put him behind bars and delivered the death penalty to him. I watched, expressionless, as they injected him with a poison that would kill him almost immediately. In his last moments, I’m sure he was thinking of his God."
    show image "Files.png" at left, files_pan2
    "Avery McMillan… Known as a loving father and good husband. His neighbors liked him and nobody seemed to think badly of him at all. He had three children who adored him: two twin boys and a girl…"
    "My heart almost stops when I see the daughter’s name, and yet part of me isn’t surprised at all. The puzzle pieces fit perfectly, but all too late."
    "Elena. His daughter’s name is Elena McMillan. Frantically, I go through the files more… I knew that! I watched countless times as his family visited him! How could I forget something like that? How could I forget something as important as that!?"
    play music rainy fadeout 1
    nvl clear
    rain_nvl "{w=1.3}Memories begin to float to the surface… Memories I’d forgotten—that I’d been forced to forget. I watch, a sick feeling in my gut, as Avery McMillan tells his daughter that he will always be with her." with dissolve
    extend "\n\nAfter the trial, his family is put under protection to prevent them from being massacred—literally or figuratively—by the rest of the world. I watch the McMillan family file quietly into the back of a van. They are driven away on a rainy day—the day Avery McMillan is executed."
    extend "\n\nMy memory of them is wiped after that. I know that they exist… I remember his family… And yet I don’t. I don’t remember six-year-old Elena’s deep green, unfeeling eyes. I don’t remember her father telling her never to forgive or forget—never to forgive or forget {i}me{/i}."
    stop music fadeout 1
    scene black
    extend "\n\nJust as he wished, she got to know me… Maybe even learned from me."
    nvl clear
    play sound "sounds/horror.ogg"
    scene image "Elena-smile.png" with Dissolve(0.1)
    scene black with dissolve
    "The electricity in the office goes out."
    "And yet, despite the odds, I’m in peace as the McMillans’ God tries to take me."
    $ persistent.true_ed = True
    play music "sounds/d_34a.ogg"
    "You have reached the {b}True Ending{/b}! Congratulations on clearing The Elevator. Please consider {a=http://feudal.polldaddy.com/s/elevator}filling out a short survey{/a} (also reachable by navigating to {b}http://bit.ly/IACoYR{/b} in your web browser) to let us know how your experience went."
    return